#usage "<b>Renumber the parts of a schematic</b>\n"
       "<p>"
       "<author>Author: Oliver Saal http://www.oliver-saal.de/</author>"

#include "oslib.inc"

// THIS PROGRAM IS PROVIDED AS IS AND WITHOUT WARRANTY OF ANY KIND, EXPRESSED OR IMPLIED

string strInfo = "<b>ATTENTION<p>\n" +
       "Please verify that your corresponding layout file (if already existing) " +
       "has been loaded with the schematic file.<p>\n" +
       "Otherwise back-/forward-annotation will not work afterwards.</b><p>\n" +
       "This version renumbers only devices with package (no supply) " +
       "sorted by sheets and coordinates (vertical/descending, horizontal/ascending).<p>\n";

int i, idx;			// helpers...
string strPrefix;		// helpers...

int descy = 1;			// set to 0 sorting ascending
int descx = 0;			// set to 1 sorting descending
int iWhat=0;			// 0=All sheets, 1=Only components inside rect on layer 95 (Names)
int iStartNumber=1;
string c, cmd;			// variables for script generation
string strOldNames=" ", strForbiddenNames=" ";

// elements to rename
// STRUCT {
numeric string oldName[];	// old name
numeric string newName[];	// new name
int x[],y[];			// position in mil
int sh[];			// sheet
// }
int sortidx[];			// sort-index, "pointer-array" to elements
int iCount=0;			// number of elements

// start numbers
// STRUCT {
string prefix_name[];		// prefix
int prefix_number[];		// next number to use
// }
int iPrefixCount=0;

void AppendPartToRename(UL_PART p)
{
int i;
	// has package?
	if (!p.device.package) return;

	// propere name with prefix and number?
	if (GetNumberIndex(p.name) <= 0) return;

	// check if part was already added
	for (i=0; i<iCount; i++)
	{
		if (oldName[i] == p.name) return;
	}

	// add part
	oldName[iCount] = p.name;
	p.instances(I)
	{
//		sprintf (c, "      Sheet %d Pos (%f %f)\n", I.sheet, u2mil(I.x), u2mil(I.y));
//		cmd += c;
		if (I.sheet > 0 && (sh[iCount] == 0 || I.sheet <= sh[iCount] && u2mil(I.y) >= y[iCount] && u2mil(I.x) <= x[iCount]))
		{
			sh[iCount] = I.sheet;
			x[iCount] = u2mil(I.x);
			y[iCount] = u2mil(I.y);
		}
	}
	sortidx[iCount] = iCount;
	strOldNames += p.name + " ";
	iCount++;
}

void DescendingY(void)
{
	for (int ny = 0; ny < iCount; ny++) 
	{
		y[ny] = 0 - y[ny];
	}
}

void DescendingX(void)
{
	for (int nx = 0; nx < iCount; nx++)
	{
 		x[nx] = 0 - x[nx];
	}
}

int GetNextNumber (string strPrefix)
{
int i=0, idx=-1, iRet;
	for (i=0; i<iPrefixCount && idx == -1; i++)
	{
		if (prefix_name[i] == strPrefix) idx = i;
	}
	if (idx == -1)
	{
		idx = iPrefixCount;
		iPrefixCount++;
		prefix_name[idx] = strPrefix;
		prefix_number[idx] = iStartNumber;
	}
	iRet = prefix_number[idx];
	prefix_number[idx]++;
	return (iRet);
}


////////////////////////////////////////////////////////////////////////////////////////////////////
/// START
////////////////////////////////////////////////////////////////////////////////////////////////////
if (!schematic)
{
	dlgMessageBox(usage + "<hr><b>ERROR: No schematic!</b><p>\nThis program can only work in the schematic editor.");
	exit(1);
}

///////////////////////////////////////////
// Main Dialog
///////////////////////////////////////////

int iResult = dlgDialog("Renumber schematic")
{
	dlgLabel(strInfo);
	dlgGroup("Options")
	{
		dlgRadioButton("All sheets", iWhat);
		dlgRadioButton("Only components inside rectangle(s) on layer 95 (Names)", iWhat);
		dlgSpacing(5);
		dlgHBoxLayout { dlgLabel("Start with number: "); dlgIntEdit(iStartNumber, 1, 99999); }
	}
	dlgHBoxLayout 
	{
		dlgGroup("Sort X") 
		{
  			dlgRadioButton("&Ascending (Left ==> Right)", descx);
  			dlgRadioButton("&Descending (Right ==> Left)", descx);
		}
  		dlgGroup("Sort Y") 
		{
  			dlgRadioButton("A&scending (Bottom ==> Top)", descy);
			dlgRadioButton("D&escending (Top ==> Bottom)", descy);
   		}
	}
	dlgSpacing(10); 
	dlgHBoxLayout
	{
		dlgStretch(1); 
		dlgPushButton("Start") dlgAccept();
		dlgPushButton("Cancel") dlgReject();
		dlgStretch(1); 
	}
};

if (iResult == 0) exit(0);

///////////////////////////////////////////
// Extract Parts
///////////////////////////////////////////
strForbiddenNames = " ";
schematic(SCH)
{
	// find elements to rename 
	SCH.sheets(SH)
	{
		if (iWhat == 0)
		{ // All elements
			SH.parts(P)
			{
				AppendPartToRename(P);
			}
		}
		else if (iWhat == 1)
		{ // Only elements inside rectangle(s) on layer 95 (Names)
			SH.rectangles(R)
			{
				if (R.layer == 95)
				{
					SH.parts(P)
					{
						if (isPartInRectangle (P, R)) AppendPartToRename(P);
					}
				}
			}
		}
	}

	// find forbidden names
	SCH.parts(P)
	{
		if (strstr(strOldNames, " " + P.name + " ") < 0) strForbiddenNames += P.name + " ";
	}
}

//dlgMessageBox ("<p>" + strOldNames + "<p>" + strForbiddenNames);

if (iCount == 0)
{
	dlgMessageBox ("There are no parts to rename.");
	exit(0);
}

// check if temporary names are available
for (i=0; i<iCount; i++)
{
	if (strstr(strForbiddenNames, " $"+oldName[i]+" ") >= 0)
	{
		dlgMessageBox ("<b>Error! Name '$"+oldName[i]+"' already exists!</b><p>This name is needed for temporarly renaming the parts.");
		exit (2);
	}
}

///////////////////////////////////////////
// Sort Arrays
///////////////////////////////////////////
if (descy) DescendingY();	// change sign of y-coordinate
if (descx) DescendingX();	// change sign of x-coordinate
sort(iCount, sortidx, sh, y, x);
if (descy) DescendingY();	// change sign of y-coordinate
if (descx) DescendingX();	// change sign of x-coordinate

///////////////////////////////////////////
// Determine new names
///////////////////////////////////////////
int iNumber=0;
string strNewName;

for (i=0; i<iCount; i++)
{
	idx = sortidx[i];
	strPrefix = ElementPrefix(oldName[idx]);
	iNumber	= GetNextNumber (strPrefix);
	sprintf (strNewName, "%s%d", strPrefix, iNumber);
	if (strstr(strForbiddenNames, " " + strNewName + " ") >= 0)
	{
		dlgMessageBox ("<b>Error! Name '"+strNewName+"' already exists!</b><p>A part with this name already exists and could not be renamed. It's outside the rectangle.");
		exit (2);
	}
	newName[idx] = strNewName;
}

for (i=0; i<iCount; i++)
{
	sprintf (c, "%s %d (%d %d)", oldName[i], sh[i], x[i], y[i]);
	cmd += c + "\n";
}

///////////////////////////////////////////
// Generate SCRIPT
///////////////////////////////////////////

cmd = "GRID MIL 100 OFF;\n";
cmd += "DISPLAY NONE 94;\n";

// Rename all parts to a temporary name
for (i=0; i<iCount; i++)
{
	cmd += CmdEditSheet(sh[i]);
	sprintf (c, "NAME $%s (%d %d);\n", oldName[i], x[i], y[i]);
	cmd += c;
}

// Rename parts
for (i=0; i<iCount; i++)
{
	cmd += CmdEditSheet(sh[i]);
	sprintf (c, "NAME %s (%d %d);\n", newName[i], x[i], y[i]);
	cmd += c;
}

//cmd += CmdEditSheet(1);
cmd += "GRID LAST;\n";
cmd += CmdDisplayVisibleLayers();

///////////////////////////////////////////
// Show finish dialog
///////////////////////////////////////////
numeric string renaming[];
string maxnumbers[];
int iSelRenaming, iSelMaxNumbers;

for (i=0; i<iCount; i++)
	renaming[i] = oldName[i] + "\t" + newName[i];

for (i=0; i<iPrefixCount; i++)
{
	sprintf (maxnumbers[i], "%s\t%d\t%d", prefix_name[i], prefix_number[i]-1, prefix_number[i]-iStartNumber);
}

iResult = dlgDialog("Summary and execute") 
{
	dlgTabWidget 
	{
		dlgTabPage ("Summary")
		{
			dlgSpacing(5);
			dlgHBoxLayout
			{
				dlgSpacing(5);
				dlgGroup("Renaming") { dlgListView ("Old name\tNew Name", renaming, iSelRenaming); }
				dlgSpacing(5);
				dlgGroup("Max. Numbers") { dlgListView ("Prefix\tMax. number\tCount", maxnumbers, iSelMaxNumbers); }
				dlgSpacing(5);
			}
			dlgSpacing(5);
		}
		dlgTabPage ("Script")
		{
			dlgTextEdit(cmd);
			dlgHBoxLayout 
			{
				dlgStretch(1);
				dlgPushButton("Save...") 
				{
					string dest = dlgFileSave ("Save Script File", "renumber-sch-os.scr", "*.scr");
					if (dest != "") output (dest, "wt") { printf(cmd); }
				}
				dlgSpacing(5);
			}
			dlgSpacing(5);
		}	
	}
	dlgSpacing(10);
	dlgHBoxLayout 
	{
		dlgStretch(1);
		dlgPushButton("+&Execute") dlgAccept();
		dlgSpacing(5);
		dlgPushButton("-&Cancel") dlgReject();
		dlgStretch(1);
	}
};

if (iResult)
	exit(cmd);
else
	exit(0);